Lessons XI : Dùng Dialogs

Chương Mười Một – Dùng Dialogs

Tác giả: Sưu tầm       ZZZZZZZZZZZZZZZZZZZZZ

Dialogs (giao thoại) được dùng để hiển thị tin tức và nhận mouse hay keyboard input từ users tùy theo tình huống. Chúng được dùng để tập trung sự chú ý của users vào công tác đương thời của program nên rất hữu dụng trong các chương trình của Windows.

Có nhiều dạng Dialogs, mỗi thứ áp dụng cho một hoàn cảnh riêng biệt. Trong chương nầy ta sẽ bàn qua 4 loại Dialogs chính và nghiên cứu về khi nào và cách nào ta dùng chúng:

  1. Message Boxes
  2. Input Boxes
  3. Common Dialogs
  4. Custom Dialogs

Message Boxes

Message Boxes được dùng để nhắc nhở user một chuyện gì, và đòi hỏi một phản ứng nào đó từ user. Thí dụ như khi ta chấm dứt program MSWord mà chưa lưu trử hồ sơ thì MSWord sẽ nhắc ta lưu trử nó bằng Dialog dưới đây:

 
Trong trường hợp nầy user có thể click một trong 3 buttons. Nếu click Yes thì sẽ xúc tiến việc lưu trử hồ sơ trước khi kết thúc program MSWord. Nếu click No thì MSWord sẽ lặng lẽ kết thúc. Nếu click Cancel thì có nghĩa user đổi ý việc chấm dứt program và trở lại tiếp tục dùng MSWord.
Ta dùng routine MsgBox để hiển thị Message Box như coding trong hình dưới đây:

 

Parameter (thông số) thứ nhất của MsgBox là text message Close the program down?, parameter thứ nhì là tập hợp của icon (vbQuestion) và số buttons (vbOKCancel) bằng cách cộng hai constants: vbQuestion + vbOKCancel (hai buttons OK và Cancel), parameter thứ ba là title (tiêu đề) của Dialog.

Trong thí dụ MSWord bên trên Constant của icon và buttons là vbExclamation + vbYesNoCancel (ba buttons Yes, No và Cancel).

Ta chọn số và loại buttons theo bảng dưới đây:

Constant Các buttons
vbOKOnly OK
vbOKCancel OK   Cancel
vbYesNo Yes   No
vbRetryCancel Retry   Cancel
vbYesNoCancel Yes   No   Cancel
vbAbortRetryIgnore Abort   Retry   Ignore

Constant của các icons ta có thể dùng là vbCritical, vbQuestion, vbExclamationvbInformation.

Khi một Message Box được mở ra, cả program ngừng lại và đợi user phản ứng. Ta nói Message Box được hiển thị trong Modal Mode, nó dành mọi sự chú ý và tạm ngưng các execution khác trong cùng program. Sau khi user click một button, Message Box sẽ biến mất và program sẽ tiếp tục chạy từ hàng code ngay dưới hàng MsgBox.

Trong thí dụ trên ta dùng MsgBox như một Sub, nhưng ta cũng có thể dùng MsgBox như một Function để biết user vừa mới click button nào. Function MsgBox returns một value (trả về một giá trị) mà ta có thể thử biết để theo đó thi hành. Thí dụ như:

Private Sub CmdPrompt_Click() 
   Dim ReturnValue As Integer 
   ReturnValue = MsgBox("Close the program down", vbQuestion + vbOKCancel, "Exit Program") 
   Select Case ReturnValue 
   Case vbOK 
      MsgBox "You clicked OK" 
   Case vbCancel 
      MsgBox "You clicked Cancel" 
   End Select 
End Sub

Các trị số Visual Basic intrinsic constants mà Function MsgBox returns là:

Trị số Tên Const
1 OK VbOK
2 Cancel vbCancel
3 Abort vbAbort
4 Retry vbRetry
5 Ignore vbIgnore
6 Yes vbYes
7 No VbNo

Bạn có thể hiển thị Text message trong Message Box thành nhiều hàng bằng cách dùng Constant vbCrLf (CarriageReturn và LineFeed) để đánh dấu những chỗ ngắt khúc như sau:

MsgBox "This is the first line" & vbCrLf & " followed by the second line"

Nếu bạn thấy mình thường dùng MsgBox với cùng một icon và những buttons, nhưng có Text message khác nhau, bạn có thể viết một Global Subroutine trong .BAS module để dùng lại nhiều lần. Thí dụ bạn có một Global Sub như sau:

Public Sub DisplayError(ByVal ErrMess As String ) 
   MsgBox ErrMess, vbCritical + vbOKOnly, "Error" 
End Sub

 

Mỗi lần muốn hiển thị một Error message bạn chỉ cần gọi Sub DisplayError với Text message mà không sợ dùng lầm lẫn icon. Sau nầy muốn đổi cách hiển thị Error message chỉ cần edit ở một chỗ. Nếu user muốn bạn lưu trữ tất cả mọi errors xẩy ra lúc run-time, bạn chỉ cần thêm vài hàng code trong Sub DisplayError để viết Error message vào một text file.

Input Boxes

Với Message Boxes, user chỉ có thể click lên một button. Đôi khi ta muốn user đánh vào thêm một ít dữ kiện, trong trường hợp ấy ta có thể dùng Input Boxes.

Input Boxes giống giống Message Box, nhưng nó chuyên nhận input data từ user và không hiển thị một icon. Thí dụ:

Private Sub CmdGreeting_Click() 
   Dim strReply As String 
   strReply = InputBox$("Please enter your name", "What 's your name?", "John", 2000, 1000)
   MsgBox "Hi " & strReply & ", it 's great to meet you!", vbOKOnly, "Hello"
End Sub

 

Để ý các parameters của Function InputBox$. Parameter thứ nhất là Text message, parameter thứ hai là Title của Dialog, parameter thứ ba là Default Input Value. Đây là value được hiển thị sẵn trong Input Box khi nó xuất hiện, nếu đó là input user thường đánh vào thì user chỉ cần click nút OK là đủ. Hai parameters cuối cùng là Optional (nhiệm ý, có cũng được, không có cũng không sao). Nó là X,Y coordinates của Input Box trong đơn vị twips. Hệ thống tọa độ lấy góc trên bên trái làm chuẩn với X=0, Y=0.

 

Input Box có hai dạng Functions:

  • InputBox$ – returns một String đàng hoàng
  • InputBox – returns một String nằm trong Variant variable

Nếu bạn click nút Cancel thì returned Value là empty string, bạn có thể test empty string để nhận diện trường hợp nầy.
Dưới đây là một thí dụ dùng Function InputBox:

Private Sub CmdFortuneTeller_Click() 
   Dim varValue As Variant 
   Dim intAge As Integer 
   varValue = InputBox("Please enter your age", "How old are you?", "18") 
   If IsNumeric(varValue) Then 
      intAge = Val(varValue) 
      If intAge < 20 Then 
         MsgBox "You are a young and ambitious person", vbOKOnly, "Observation" 
      Else 
         MsgBox "You are a matured and wise person", vbOKOnly, "Observation" 
      End If 
   Else 
      MsgBox "Oh oh! - please type your age!", vbCritical + vbOKOnly, "Input Error" 
   End If 
End Sub

Khi nào nên dùng Input Boxes

Mặc dầu Input Boxes rất dễ dùng, trên thực tế rất ít khi ta dùng nó vì những lý do sau đây:

  • Ta không thể làm gì được trong lúc user input data, phải đợi sau khi user click OK thì mới bắt đầu xử lý input textstring. Ngược lại nếu ta dùng một Textbox trong một Form thông thường, ta có thể code trong các Event handlers của Events KeyPress hay Change để kiểm soát các keystrokes của user.
  • Input Boxes chỉ cho ta đánh vào một text string duy nhất. Nhiều khi ta muốn user đánh vào nhiều thứ nên cần phải có một form riêng.
  • Sau cùng, Input Boxes xem không đẹp mắt. Program dùng Input Boxes có vẻ như không chuyên nghiệp, do đó ta cần phải dùng Custom Dialogs.

Common Dialogs

Bạn có để ý thấy hầu như mọi programs trong Windows đều có cùng những dialogs để Open và Save files ? Và hầu như tất cả programs đều có cùng dialogs để chọn màu, font chữ hay để in ? Đó là vì các Dialogs thông dụng ấy thuộc về Common Dialog Library của MSWindows và cho phép các program gọi.

Muốn dùng các Dialogs ấy trong VB6 ta phải reference Comdlg32.ocx bằng IDE Menu command Project | Components… rồi chọn và Apply Microsoft Common Dialog Control 6.0.

 

Microsoft Common Dialog Control 6.0 cho ta sáu dạng Dialogs tùy theo gọi Method nào:

Tên Method
Open File ShowOpen
Save File ShowSave
Color ShowColor
Font ShowFont
Print ShowPrinter
Help ShowHelp

Open và Save File Dialogs

Bạn hãy mở một Project mới với một button tên CmdOpen trong Form1 và đánh vào code sau đây cho Sub CmdOpen_Click:

Private Sub CmdOpen_Click() 
   On Error GoTo DialogError 
   With CommonDialog1 
      .CancelError = True  ' Generate Error number cdlCancel if user click Cancel
      .InitDir = "E:\VB6"   ' Initial (i.e. default ) Folder   
      .Filter = "Executables (*.exe) | *.exe| Batch Files (*.bat)| *.bat" 
      .FilterIndex = 1  ' Select ""Executables (*.exe) | *.exe" as default
      .DialogTitle = "Select a program to run" 
      .ShowOpen   ' Lauch the Open Dialog
      MsgBox "You selected " & .FileName, vbOKOnly + vbInformation, "Open Dialog" 
   End With 
   Exit Sub 
DialogError: 
   If Err.Number = cdlCancel Then 
      MsgBox "You clicked Cancel!", vbOKOnly + vbInformation, "Open Dialog" 
      Exit Sub 
   Else 
      MsgBox "Error in Dialog's use: " & Err.Description, vbOKOnly + vbCritical, "Error"
      Exit Sub 
   End If 
End Sub

Hãy chạy program ấy và click button Open, program sẽ hiển thị error message dưới đây:

 

Đó là vì ta quên bỏ một Microsoft Common Dialog Control 6.0 vào Form1. Vậy bạn hãy doubleclick icon của nó trong ToolBox. Bây giờ hãy chạy program lại và click button Open để hiển thị Open Dialog.

 

Bạn có thể chọn folder nào tùy ý bằng cách di chuyển từ folder nầy qua folder khác hay thay đổi disk drive. Nếu bạn click vào bên phải của combobox File of type, nó sẽ dropdown để cho thấy bạn có thể chọn một trong hai loại Files như liệt kê trong statement:

      .Filter = "Executables (*.exe) | *.exe| Batch Files (*.bat)| *.bat"

Sau khi chọn một Filename có sẵn hay đánh một tên vào File name textbox, bạn click Open. Sau đó, CommonDialog1.Filename sẽ chứa tên file bạn đã chọn hay đánh vào.

 
Vì ta cho .CancelError = True nên nếu user click Cancel program sẽ generate một Error số 32755 (cdlCancel). Ở đây ta bắt Error ấy bằng cách dùng On Error GoTo DialogError và thử Err.Number= cdlCancel để hiển thị Error message dưới đây:

 

Save Dialog cũng tương tự như Open Dialog, ta dùng method ShowSave để hiển thị nó.

 

Trong thí dụ trên ta định nghĩa các properties của CommonDialog1 bằng code. Bạn cũng có thể dùng Properties Windows để định nghĩa chúng như dưới đây:

 

Ngoài ra, bạn cũng có thể dùng các trang Properties của CommonDialog1 để định nghĩa Properties lúc thiết kế bằng cách right click Commondialog1 trên Form1 rồi chọn Properties:

 

Properties Pages Dialog sẽ hiển thị với Tab Open/Save As có sẵn lúc đầu, bạn có thể đánh các tin tức như sau:

 

Color Dialog

Color Dialog cho user một cách chọn màu rất dễ dùng. Ngoài những màu có sẵn, user có thể tự tạo ra một màu rồi cho nó thêm vào trong bảng màu được cung cấp, gọi là Windows Palette bằng cách click button Add to Custom Colors.

 
Bạn tạo ra một màu bằng cách click chỗ có màu theo ý trong bảng màu lớn hình vuông rồi nắm hình tam giác bên phải kéo lên, kéo xuống để thay đổi độ đậm của màu như hiển thị trong hộp vuông Color|Solid. Khi vừa ý với màu hiển thị, bạn click button Add to Custom Colors, màu ấy sẽ được cho thêm vào nhóm Custom Colors nằm phía dưới, bên trái.

 
Ta dùng method ShowColor để hiển thị Color Dialog. Sau khi user đã chọn một màu rồi, ta có thể trực tiếp assign nó cho property ForeColor hay BackColor của một control. Trong thí dụ dưới đây cái màu mà user vừa chọn được assigned cho background của picturebox Picture1:

Private Sub CmdSelectColor_Click() 
   On Error GoTo NoColorChosen 
   With CommonDialog1 
      .CancelError = True 
      ' Entire dialog box is displayed, including the Define Custom Colors section
      .Flags = cdlCCFullOpen 
      .ShowColor  ' Launch the Color Dialog
      Picture1.BackColor = .Color  ' Assign selected color to background of Picture1
      Exit Sub 
   End With 
NoColorChosen: 
   ' Get here if user clicks the Cancel button
   MsgBox "You did not select a color!", vbInformation, "Cancelled" 
   Exit Sub 
End Sub

Font Dialog

Font Dialog cho ta chọn Font cho màn ảnh hay printer và chọn màu để dùng cho chữ của Font. Ta dùng method ShowFont để hiển thị FontDialog. Các chi tiết trình bày trong Font Dialog tùy thuộc vào trị số của Flags như sau:

Constant Trị số Hiệu quả
cdlCFScreenFonts 1 Chỉ hiển thị các Fonts printer hổ trợ
cdlCFPrinterFonts 2 Chỉ hiển thị các Fonts của màn ảnh, chưa chắc tất cả đều được printer hổ trợ
cdlCFBoth 3 Hiiển thị các Fonts màn ảnh và printer
cdlCFScalableOnly &H20000 Chỉ hiển thị các scalable Fonts như TrueType fonts mà bạn đã cài vào máy

Nếu bạn muốn cho user nhiệm ý để chọn màu thì thêm 256 vào trị số của Flags.

 

Dưới đây là code để cho user chọn Font và màu của Label1.

Private Sub CmdSelectFont_Click() 
   On Error GoTo NoFontChosen 
   CommonDialog1.CancelError = True 
   ' Causes the dialog box to list only the screen fonts supported by the system.
   CommonDialog1.Flags = cdlCFScreenFonts + 256  ' Add 256 to include Color option
   CommonDialog1.ShowFont  ' Launch the Font Dialog
   With Label1.Font 
      .Bold = CommonDialog1.FontBold 
      .Italic = CommonDialog1.FontItalic 
      .Name = CommonDialog1.FontName 
      .Size = CommonDialog1.FontSize 
      .Strikethrough = CommonDialog1.FontStrikethru 
      .Underline = CommonDialog1.FontUnderline 
   End With 
   Label1.ForeColor = CommonDialog1.Color 
   Label1.Caption = "Hello world!!!, this is a Font Dialog Demo" 
   Exit Sub 
NoFontChosen: 
   MsgBox "No font was chosen!", vbInformation, "Cancelled" 
   Exit Sub 
End Sub

Chú ý: Nếu bạn quên cho Flags một trong những hằng số nói trên program sẽ cho một Error message như sau:

 

Print Dialog

Print Font cho ta một giao diện cũng giống như trong Microsoft Office để chọn những nhiệm ý về việc in. Với Print Dialog ta có thể chọn printer nào với những đặc tính nào bằng cách click button Properties hay button Preferences. Ta cũng có thể quyết định in từ trang nào đến trang nào của document và in bao nhiêu copies. Chỉ có điều phải lưu ý là nếu user dùng Print Dialog để chọn một Printer khác mà trong Print Dialog ta đã chọn Property PrinterDefault = True thì Printer ấy sẽ trở thành Default Printer và nó cũng sẽ có hiệu lực vĩnh viễn trong cả Windows cho đến khi user thay đổi lại.
Khác với Color và Font Dialogs, Print Dialog không đòi hỏi ta phải cho một trị số của Property Flags. Ta chỉ cần dùng Method ShowPrinter để hiển thị Print Dialog. Ba properties thường được dùng nhất sau khi user chọn các nhiệm ý của Print Dialog là Copies, FromPageToPage. Để cho user các default values của những properties nầy, bạn có thể để sẵn các trị số trước khi hiển thị Print Dialog.

 
Dưới đây là code mẫu dùng print Dialog:

Private Sub CmdSelectPrinter_Click() 
   With CommonDialog1 
      .FromPage = 1 
      .ToPage = 1 
      .Copies = 1 
      .ShowPrinter 
   End With 
End Sub

Help Dialog

Ta dùng method ShowHelp để hiển thị các thông tin giúp đỡ, nhưng nhớ phải cho CommonDialog ít nhất trị số của các properties HelpFileHelpCommand.

Private Sub CmdHelp_Click() 
   CommonDialog1.HelpFile = "YourProgram.hlp" 
   CommonDialog1.HelpCommand = cdlHelpContents 
   CommonDialog1.ShowHelp 
End Sub

Để biết thêm chi tiết về cách dùng ShowHelp, highlight chữ HelpContext trong source code VB6 rồi ấn phím F1 và chọn MsComDlg.

Custom Dialogs

Nhiều khi Message Box, Input Box hay các dạng Common Dialogs vẫn không thích hợp cho hoàn cảnh lập trình. Trong trường hợp ấy bạn có thể dùng một Form bình thường để làm thành một Dialog cây nhà, lá vườn. Nó hơi mất công hơn một chút, nhưng thứ nhất nó có những màu sắc giống như các Forms khác trong chương trình, và thứ hai ta muốn làm gì tùy ý. Chỉ có cái bất lợi là chương trình sẽ dùng nhiều tài nguyên hơn, nói thẳng ra là cần thêm một ít memory.

Sau đây ta thử triển khai một Login Form tổng quát, có thể dùng trong nhiều trường hợp. Khi khởi động, program nầy sẽ hiển thị một Login form yêu cầu user đánh vào tên và mật khẩu. Sau đó, nếu tên và mật khẩu hợp lệ thì cái Form chính của program mới hiện ra. Cách ta thực hiện là cho program khởi động với một Sub Main trong .BAS Module. Sub Main sẽ gọi Sub GetUserInfo (cũng nằm trong cùng Module) để hiển thị form frmLogin trong Modal mode để nó làm việc cùng một cách như Message Box, Input Box hay Common Dialogs.
Khi form frmLogin được dấu kín bằng statement Me.Hide thì execution trong Sub GetUserInfo sẽ tiếp tục để chi tiết điền vào các textboxes txtUserName và txtPassword được trả về local variables strUserName và strPassword. Mã nguồn của Sub Main và Sub GetUserInfo được liệt ra dưới đây:

Sub Main() 
   Dim strUserName As String 
   Dim strPassword As String 
   ' Call local Sub getUserInfo to obtain UserName and Password
   GetUserInfo strUserName, strPassword 
   If strUserName = "" Then 
      MsgBox "Login failed or aborted", vbInformation, "login Aborted" 
   Else 
      MsgBox "User " & strUserName & " logged in with password " & strPassword, vbInformation, "Login accepted" 
      ' Check UserName and Password here
      ' If valid password then show the Main form of the program which is implemented separately...
      ' frmMain.Show
   End If 
End Sub
 
Private Sub GetUserInfo(ByRef sUserName As String, ByRef sPassword As String) 
   ' Invoke frmLogin form in Modal mode
   frmLogin.Show vbModal 
   ' As soon as frmLogin is hidden, the execution gets here
   sUserName = frmLogin.txtUserName  ' assign the form's txtUserName to sUserName
   sPassword = frmLogin.txtPassword  ' assign the form's txtPassword to sPassword
   Unload frmLogin  ' Unload form frmLogin
End Sub

Login form được hiển thị như dưới đây:

 
Sau khi user điền chi tiết và click OK, tạm thời ta chỉ hiển thị một thông điệp để xác nhận các chi tiết ấy.

 
Trong tương lai, bạn có thể viết thêm code để kiểm tra xem tên và mật khẩu có hiệu lực không. Có một vài chi tiết về form frmLogin để nó làm việc giống giống một Common Dialog:

  • Ta cho property BorderStyle của frmLogin là Fixed Dialog.
  • Ta cho Property PasswordChar của textbox txtPassword bằng “*” để khi user điền mật khẩu, ta chỉ thấy một hàng dấu hoa thị.
  • Ta cho Property StartupPosition của form là CenterScreen.
  • Property Default của button cmdOK là True để khi user ấn phím Enter trong form là coi như tương đương với click button cmdOK.
  • Tương tợ như thế, Property Cancel của button cmdCancel là True để khi user ấn phím Esc trong form là coi như tương đương với click button cmdCancel.

Tạm thời coding của event click của cmdOK và cmdCancel chỉ đơn giản như liệt kê dưới đây:

Private Sub CmdCancel_Click() 
   ' Clear txtUserName and txtPassword
   txtUserName = "" 
   txtPassword = "" 
   ' Hide the Form to get out of Modal mode
   Me.Hide 
End Sub 
  
  
Private Sub CmdOK_Click() 
   ' Hide the Form to get out of Modal mode
   Me.Hide 
End Sub

 

  1. Leave a comment

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s

%d bloggers like this: